Pitkän matematiikan ylioppilaskokeen ratkaisut syksyllä 2000

Ohessa syksyn 2000 ylioppilaskirjoitusten pitkän matematiikan tehtävät ratkaistuina Mathematicalla.

Pohdittavaksi: Pitäisikö tällaiset työkalut sallia ylioppilaskirjoituksissa jossakin läheisessä tulevaisuudessa? Millaista matematiikkaa koulussa tulisi opettaa? Menetetäänkö jotakin olennaista, jos ohjelmistojen käyttö sallitaan?

Simo K. Kivelä

Tehtävä 1

(x^(n - 1))^(n - 1) (x^n)^(2 - 
                n)
 // PowerExpand // 
      Simplify

a^(1/
                3) ((a^2)^(1/3) - (a^5)^(1/
                    3))
 // PowerExpand // 
      Expand

Tehtävä 2

yhtalo =  Sqrt[x - 2] == 1  +  2/Sqrt[x - 2]

Solve[yhtalo, x]

Tehtävä 3

aika1 =  s/v

aika2 =  0.6 s/v  +  0.4 s/(1.2 v)

100 (aika1  -  aika2)/aika1

Tehtävä 4

ehto1 =  h/x  ==  Tan[3.5 Degree]

ehto2 =  h/y  ==  Tan[2.5 Degree]

ehto3 =  y  ==  x  +  500

Solve[{ehto1, ehto2, ehto3}, {x, y, h}]

Tehtävä 5

oletus1 =  x  +  y  + z  ==  0

oletus2 =  x^2  +  y^2  +  z^2  ==  1

vaitos =  x y  +  y z  +  z x  ==  -1/2

Simplify[vaitos, {oletus1, oletus2}]

Tehtävä 6

p[x_] :=  a x^3  +  b x^2  +  c x  +  d

ehto1 =  p[2]  ==  0

ehto2 =  p'[2]  ==  0

ehto3 =  p[3]  ==  15

ehto4 =  p'[1]  ==  0

kertoimet =  
      Solve[{ehto1, ehto2, ehto3, ehto4}, {a, b, c, d}]

p[x] /. First[kertoimet]

Tehtävä 7

p2 = todennäköisyys sille, että ainakin kaksi itää

p2 =  
      1  -  Sum[
          Binomial[n, k] p^k (1 - p)^(n - k), {k, 0, 1}]

Solve[(p2 /. p -> 0.7) ==  0.99, n]

Tai:

Table[p2 /. p -> 0.7, {n, 0, 10}]

Siis: vähintään 7.

Tehtävä 8

Remove["Global`*"]

p =  {p1, p2};  a =  {a1, a2};  b =  {b1, b2};  
    c =  {c1, c2};

oletus1 =  (p  -  a) . (b  -  c)  ==  0

oletus2 =  (p  -  b) . (c  -  a)  ==  0

vaitos =  (p  -  c) . (a  -  b)  ==  0

Simplify[vaitos, {oletus1, oletus2}]

P on kolmion korkeusjanojen leikkauspiste. Lause: Korkeusjanat leikkaavat samassa pisteessä.

Tehtävä 9

r = 1/2

Piirretään kuvio:

ympyra =  
        ParametricPlot[r {Cos[t], Sin[t]}, {t, 0, 2 π}, 
          DisplayFunction -> Identity];
kaari =  
        ParametricPlot[0.1 r {Cos[t], Sin[t]}, {t, -0.3, π/2}, 
          DisplayFunction -> Identity];
janat =  
        Graphics[
          Line[{{0, r}, {0, -r}, 
              r {Cos[-0.3], Sin[-0.3]}, {0, 
                0}}]];
$TextStyle = {FontSize -> 12}; 
    tekstit =  
      Graphics[{Text["d", r {0.5, -0.5}], 
          Text["r", r {0.15, 0.5}], 
          Text["x", r {0.15, 0.15}]}];
Show[ympyra, janat, kaari, tekstit, 
      DisplayFunction -> $DisplayFunction, 
      AspectRatio -> Automatic]

d =  Sqrt[r^2  +  r^2  - 2 r^2  Cos[π - x]]

v1 =  10

v2 =  5

t(x) on kokonaisaika:

t[x_] :=  Evaluate[r x/v1  +  d/v2]

Derivaatan nollakohdat ja välin päätepisteet:

nollakohdat =  Solve[t'[x] == 0, x]

t[x] /. First[nollakohdat] // N

t[0] // N

t[π] // N

t(x) pienin, kun x  =  π, ts. suo on kierrettävä.

Tehtävä 10

Remove["Global`*"]

a[n_] :=  (n^3  +  5 n)/6

Induktion alku:

a[1]

Induktioaskel:

Luontevaa olisi testata, tuleeko seuraavaan syötteeseen vastaukseksi True, mutta Mathematica ei kykene sieventämään lausekkeita tarvittavalla tavalla:

Simplify[
      Element[Expand[a[n + 1]], Integers], {Element[n, Integers], 
        Element[a[n], Integers]}]

Ainoa mahdollisuus lienee, että ihminen huomaa

a[n + 1]  ==  a[n]  +  n (n + 1)/2  +  1 // 
      Simplify

ja päättelee asian tästä.

Tehtävä 11

Aluksi kuvio ja eräitä määrittelyjä:

yhtalo1 =  
        3 x  -  4 y  -  4  ==  0;
yhtalo2 =  
        x  -  2 y  +  2  ==  0;
suora1 =  
        ParametricPlot[
          Evaluate[{x, y} /. First[Solve[yhtalo1, y]]], {x, -1, 10}, 
          DisplayFunction -> Identity];
suora2 =  
        ParametricPlot[
          Evaluate[{x, y} /. First[Solve[yhtalo2, y]]], {x, -1, 10}, 
          DisplayFunction -> Identity];
p[0] =  {0, -1};
q[n_] :=  q[n] =  
          Module[{}, {p[n][[1]], y} /. 
              First[Solve[(yhtalo2 /. x -> p[n][[1]]), 
                  y]]];
p[n_] :=  p[n] = 
          Module[{}, {x, q[n - 1][[2]]} /. 
              First[Solve[(yhtalo1 /. y -> q[n - 1][[2]]), 
                  x]]];
pisteet =  
        Flatten[Table[{p[n - 1], q[n - 1], p[n]}, {n, 1, 20}], 
          1];
porrasviiva =  
        Graphics[{Line[pisteet], PointSize[0.02], 
            Map[Point, pisteet]}];
Show[suora1, suora2, porrasviiva, 
      DisplayFunction -> $DisplayFunction]

Matka porrasviivaa pitkin pisteestä (Subscript[P, n - 1]) pisteeseen (Subscript[P, n]):

porras[
        n_] :=  (q[n - 1][[2]]  -  p[
                n - 1][[2]])  +  (p[n][[1]]  -  q[
                n - 1][[1]])

Table[porras[n], {n, 1, 10}]

Table[porras[n + 1]/porras[n], {n, 1, 10}]

Siis kyseessä geometrinen jono, jonka suhdeluku on 2/3. Matka pisteestä (Subscript[P, 0]) pisteeseen (Subscript[P, n]):

matka =  Sum[porras[1] (2/3)^k, {k, 0, n - 1}]

Limit[matka, n -> Infinity]

Vertaa suorien leikkauspisteen ja pisteen (Subscript[P, 0]) koordinaattien erotusten summaan:

lp =  {x, y} /. First[Solve[{yhtalo1, yhtalo2}, {x, y}]]

(lp[[1]]  -  p[
              0][[1]])  +  (lp[[2]]  -  p[
              0][[2]])

Tehtävä 12

yhtalo =  Log[x, y]  ==  Log[y, x]

Solve[yhtalo, y]

<< Graphics`ImplicitPlot`

ImplicitPlot[yhtalo, {x, 0.01, 5}, {y, 0.01, 5}, 
      PlotPoints -> {100, 100}]

Mutta kuvassa on liikaa viivoja !!!

Tehtävä 13

f[x_] :=  Integrate[Sqrt[t^2 + 1], {t, x, 3 x}]

derivaatta =  f'[x] // FullSimplify

Solve[derivaatta  ==  0, x]

Ei reaalisia nollakohtia eikä siis ääriarvoja.

Plot[f[x], {x, -5, 5}]

Tehtävä 14

Remove["Global`*"]

ehto1 =  y'[x]  ==  1/2 y[x]/x

ehto2 =  y[4]  ==  1

DSolve[{ehto1, ehto2}, y[x], x]

Tehtävä 15

testi[{x_, y_}] :=  10 x  +  4 y  ==  36

Select[Flatten[Table[{x, y}, {x, -20, 20}, {y, -20, 20}], 1], 
      testi]

testi[{2  +  2 u, 4  -  5 u}] // Simplify

Ratkaisu siis on x  =  2  +  2  u, y  =  4  -  5  u, missä u on kokonaisluku.